mod: bump to version 0.0.4

Accessing resources which are not available, the invalid page will be
rendered instead. The original attempt for access will be logged.

build.zig

@@ -4,6 +4,14 @@ pub fn build(b: *std.Build) void {
     const target = b.standardTargetOptions(.{});
     const optimize = b.standardOptimizeOption(.{});
 
+    const zlog = b.dependency("zlog", .{
+        .target = target,
+        .optimize = optimize,
+        .timestamp = true,
+        .stderr = false,
+        .file = "log",
+    });
+
     const zterm = b.dependency("zterm", .{
         .target = target,
         .optimize = optimize,
@@ -17,18 +25,7 @@ pub fn build(b: *std.Build) void {
             .optimize = optimize,
             .imports = &.{
                 .{ .name = "zterm", .module = zterm.module("zterm") },
-                .{
-                    .name = "about",
-                    .module = b.createModule(.{
-                        .root_source_file = b.path("doc/about.md"),
-                    }),
-                },
-                .{
-                    .name = "blog",
-                    .module = b.createModule(.{
-                        .root_source_file = b.path("doc/blog.md"),
-                    }),
-                },
+                .{ .name = "zlog", .module = zlog.module("zlog") },
             },
         }),
     });

build.zig.zon

@@ -1,13 +1,17 @@
 .{
     .name = .tui_website,
     // This is a [Semantic Version](https://semver.org/).
-    .version = "0.0.1",
+    .version = "0.0.4",
     .fingerprint = 0x93d98a4d9d000e9c, // Changing this has security and trust implications.
     .minimum_zig_version = "0.16.0-dev.463+f624191f9",
     .dependencies = .{
         .zterm = .{
-            .url = "git+https://gitea.yves-biener.de/yves-biener/zterm#89aeac1e968f1390bd945f734aac8612efbab179",
-            .hash = "zterm-0.3.0-1xmmELjzGwBxVlqXRHn7p-sXFU9xPxqFMxF0PY2CkzFn",
+            .url = "git+https://gitea.yves-biener.de/yves-biener/zterm#ad32e46bc9fd6d1d9b7a3615979a3b80877c9300",
+            .hash = "zterm-0.3.0-1xmmEO8PHABP4tE6BnEZllJTh6Hpza_5C9wS8s2vjwou",
+        },
+        .zlog = .{
+            .url = "git+https://gitea.yves-biener.de/yves-biener/zlog#f43034cea9a0863e618c3d0a43706ce38c8791cf",
+            .hash = "zlog-0.16.0-6JSlRx1JAADasbK5FS6Qaf0Iq1SCQaH5VZRxT2SRE2xs",
         },
     },
     .paths = .{

doc/blog.md

@@ -1,5 +1,7 @@
-# Blog
-
+---
+title: Welcome to my Blog
+date: 2025-11-01
+---
 This is the main entry page for my blog. I plan on writing on things I feel like worth sharing, mentioning for other developers, tinkers like me.
 
 The blog is currently a work in progress and will be updated once a first version of the tui website supports more dynamic contents.

doc/test.md

@@ -0,0 +1,51 @@
+---
+title: Capabilities of tui-website
+---
+Not everything that can be done with markdown can be representented by this tui-application. It is simple enough to
+support basic markdown files. Currently the text has to be manually reflowed to 120 characters, such that there is no
+issue when rendering (i.e. correct line breaks, etc.)
+
+The following list contains all the available features that are supported (with some examples below):
+
+  - unordered lists (using `-`, `+` and `*`, where the corresponding symbol is used when rendering)
+  * links
+  + blocks
+  - `inline blocks` (written as `inline blocks`)
+  * _italic_ (written as `_italic_`)
+  + **bold** (written as `**bold**`)
+  - headlines (corresponding sub heading six levels deep)
+
+Headings currently require a second newline before the list items to render correctly with a empty line in between the
+following contents and the last list item.
+
+Another paragraph.
+
+# Examples
+
+> quotes are not supported (yet)
+
+The following is a block. Which renders as follows (containing line numbers and **no code highlighting**):
+
+---
+
+```zig
+fn myFunction() void {
+    if (hasFeature()) {
+        // Feature-specific code
+    } else {
+        // Default code
+    }
+}
+
+inline fn hasFeature() bool {
+    return (comptime comptimeCheck()) and runtimeCheck();
+}
+```
+
+## Combinations are possible
+
+1. see this excellent blog post: [Conditionally Disabling Code with comptime in Zig - Mitchell Hashimoto](https://mitchellh.com/writing/zig-comptime-conditional-disable)
+
+### See deeper levels are possible and will be rendered correctly
+
+This is just some placeholder text.

src/content.zig

@@ -1,25 +1,74 @@
 pub fn Content(App: type) type {
     return struct {
-        pub fn init(allocator: Allocator) @This() {
-            _ = allocator;
-            return .{};
+        allocator: Allocator,
+        document: *const App.Model.Document,
+
+        pub fn init(allocator: Allocator, document: *const App.Model.Document) @This() {
+            return .{
+                .allocator = allocator,
+                .document = document,
+            };
         }
 
         pub fn element(this: *@This()) App.Element {
             return .{
                 .ptr = this,
                 .vtable = &.{
+                    .minSize = minSize,
                     .handle = handle,
                     .content = content,
                 },
             };
         }
 
+        fn minSize(ctx: *anyopaque, size: zterm.Point) zterm.Point {
+            const this: *const @This() = @ptrCast(@alignCast(ctx));
+            const text = this.document.content;
+            var index: usize = 0;
+            var new_size: zterm.Point = .{ .x = size.x };
+
+            for (0..text.len) |_| rows: {
+                for (0..size.x - 1) |_| { // assume that there is one cell reserved for the scrollbar
+                    if (index == text.len) break :rows;
+                    const cp = text[index];
+                    index += 1;
+
+                    switch (cp) {
+                        '\n' => break,
+                        else => {},
+                    }
+                }
+                new_size.y += 1;
+            }
+            return new_size;
+        }
+
         fn handle(ctx: *anyopaque, model: *App.Model, event: App.Event) !void {
-            _ = ctx;
+            const this: *@This() = @ptrCast(@alignCast(ctx));
             switch (event) {
-                .about => model.page = .about,
-                .blog => model.page = .blog,
+                .init => this.document = &model.document,
+                .about => {
+                    model.page.deinit(this.allocator);
+                    model.page = .about;
+
+                    model.document.deinit(this.allocator);
+                    model.document = .init(try std.fs.cwd().readFileAlloc("./doc/about.md", this.allocator, .unlimited));
+                    this.document = &model.document;
+                },
+                .blog => |path| {
+                    model.page.deinit(this.allocator);
+                    model.document.deinit(this.allocator);
+                    errdefer {
+                        if (path) |p| this.allocator.free(p);
+                        model.document = .invalidPage;
+                        model.page = .{ .blog = null };
+                    }
+
+                    model.document = .init(try std.fs.cwd().readFileAlloc(if (path) |p| p else "./doc/blog.md", this.allocator, .unlimited));
+                    model.page = .{ .blog = path };
+
+                    this.document = &model.document;
+                },
                 else => {},
             }
         }
@@ -28,16 +77,12 @@ pub fn Content(App: type) type {
             _ = ctx;
             assert(cells.len == @as(usize, size.x) * @as(usize, size.y));
 
-            const text = switch (model.page) {
-                .about => @embedFile("about"),
-                .blog => @embedFile("blog"),
-            };
+            const text = model.document.content;
             var index: usize = 0;
 
             for (0..size.y) |row| {
                 for (0..size.x) |col| {
                     const cell = row * size.x + col;
-                    assert(cell < cells.len);
 
                     if (index == text.len) return;
                     const cp = text[index];
@@ -53,6 +98,94 @@ pub fn Content(App: type) type {
     };
 }
 
+pub fn Title(App: type) type {
+    return struct {
+        pub fn element(this: *@This()) App.Element {
+            return .{
+                .ptr = this,
+                .vtable = &.{
+                    .content = content,
+                },
+            };
+        }
+
+        fn content(ctx: *anyopaque, model: *const App.Model, cells: []zterm.Cell, size: zterm.Point) !void {
+            const this: *const @This() = @ptrCast(@alignCast(ctx));
+            _ = this;
+            assert(cells.len == @as(usize, size.x) * @as(usize, size.y));
+
+            if (model.document.title) |text| {
+                for (0.., text) |idx, cp| {
+                    cells[idx].style.fg = .green;
+                    cells[idx].style.emphasis = &.{.bold};
+                    cells[idx].cp = cp;
+
+                    // NOTE do not write over the contents of this `Container`'s `Size`
+                    if (idx == cells.len - 1) break;
+                }
+            }
+        }
+    };
+}
+
+pub fn InfoBanner(App: type) type {
+    return struct {
+        left_text: []const u8 = "Build with zig",
+        right_text: []const u8 = "Yves Biener (@yves-biener)",
+
+        pub fn element(this: *@This()) App.Element {
+            return .{
+                .ptr = this,
+                .vtable = &.{
+                    .content = content,
+                },
+            };
+        }
+
+        fn content(ctx: *anyopaque, model: *const App.Model, cells: []zterm.Cell, size: zterm.Point) !void {
+            const this: *const @This() = @ptrCast(@alignCast(ctx));
+            assert(cells.len == @as(usize, size.x) * @as(usize, size.y));
+
+            for (0.., this.left_text) |idx, cp| {
+                // NOTE do not write over the contents of this `Container`'s `Size`
+                if (idx == cells.len) break;
+
+                cells[idx].style.fg = .default;
+                cells[idx].style.emphasis = &.{.dim};
+                cells[idx].cp = cp;
+            }
+
+            switch (model.page) {
+                .about => {},
+                .blog => |path| if (path) |p| page: {
+                    const start_idx = (size.x -| p.len) / 2;
+                    if (start_idx <= this.left_text.len) break :page;
+
+                    for (start_idx.., p) |idx, cp| {
+                        // NOTE do not write over the contents of this `Container`'s `Size`
+                        if (idx == cells.len) break;
+
+                        cells[idx].style.fg = .default;
+                        cells[idx].cp = cp;
+                    }
+                },
+            }
+
+            var start_idx = size.x -| this.right_text.len;
+            if (start_idx <= this.left_text.len) start_idx = this.left_text.len + 1;
+
+            for (start_idx.., this.right_text) |idx, cp| {
+                // NOTE do not write over the contents of this `Container`'s `Size`
+                if (idx == cells.len) break;
+
+                cells[idx].style.fg = .default;
+                cells[idx].style.emphasis = &.{.dim};
+                cells[idx].cp = cp;
+            }
+        }
+    };
+}
+
 const std = @import("std");
 const Allocator = std.mem.Allocator;
 const assert = std.debug.assert;

src/main.zig

@@ -1,3 +1,11 @@
+// TODO
+// - should the path containing the contents of the tui-website reside in the
+//   hardcode `./doc` directory or shall this become a compilation argument to
+//   allow for custom directory locations?
+
+// usage: tui_website <location>
+// <location>: partial path to the document without the file extension and the beginning `./doc` path
+//             ending `/` (as used from the web-world) are trimmed automatically
 pub fn main() !void {
     errdefer |err| log.err("Application Error: {any}", .{err});
 
@@ -6,7 +14,18 @@ pub fn main() !void {
 
     const allocator = gpa.allocator();
 
-    var app: App = .init(.{});
+    var arg_it = try std.process.argsWithAllocator(allocator);
+    errdefer arg_it.deinit();
+
+    // skip own executable name
+    _ = arg_it.skip();
+
+    var app: App = .init(.{
+        .page = .about,
+        .document = .init(try std.fs.cwd().readFileAlloc("./doc/about.md", allocator, .unlimited)),
+    });
+    defer app.model.deinit(allocator);
+
     var renderer = zterm.Renderer.Buffered.init(allocator);
     defer renderer.deinit();
 
@@ -18,22 +37,29 @@ pub fn main() !void {
         },
     }, .{});
     defer container.deinit();
+    var content_container: App.Container = undefined;
+    defer content_container.deinit();
 
+    // header with navigation buttons and content's title
+    {
         var header: App.Container = try .init(allocator, .{
             .size = .{
                 .dim = .{ .y = 1 },
                 .grow = .horizontal,
             },
-    }, .{});
-    var navigation: App.Container = try .init(allocator, .{
             .layout = .{
                 .separator = .{ .enabled = true },
             },
         }, .{});
+        // title
+        {
+            var title: Title = .{};
+            try header.append(try .init(allocator, .{}, title.element()));
+        }
         // about navigation button
         {
-        var button: App.Button(.about) = .init(&app.queue, .init(.default, "about"));
-        try navigation.append(try .init(allocator, .{
+            var button: NavigationButton(.about) = .init(&app.model, &app.queue);
+            try header.append(try .init(allocator, .{
                 .size = .{
                     .dim = .{ .x = 5 + 2 },
                     .grow = .vertical,
@@ -42,32 +68,82 @@ pub fn main() !void {
         }
         // blog navigation button
         {
-        var button: App.Button(.blog) = .init(&app.queue, .init(.default, "blog"));
-        try navigation.append(try .init(allocator, .{
+            var button: NavigationButton(.blog) = .init(&app.model, &app.queue);
+            try header.append(try .init(allocator, .{
                 .size = .{
                     .dim = .{ .x = 4 + 2 },
                     .grow = .vertical,
                 },
             }, button.element()));
         }
-    try header.append(navigation);
         try container.append(header);
-    var content: Content = .init(allocator);
-    try container.append(try .init(allocator, .{}, content.element()));
+    }
+    // main actual tui_website page content
+    {
+        var content: Content = .init(allocator, &app.model.document);
+        content_container = try .init(allocator, .{}, content.element());
+
+        var scrollable: App.Scrollable = .init(content_container, .enabled(.green, false));
+        // intermediate container for *padding* containing the scrollable `Content`
+        var scrollable_container: App.Container = try .init(allocator, .{
+            .layout = .{ .padding = .horizontal(2) },
+        }, .{});
+        try scrollable_container.append(try .init(allocator, .{}, scrollable.element()));
+        try container.append(scrollable_container);
+    }
+    // footer
+    {
+        var info_banner: InfoBanner = .{};
+        const footer: App.Container = try .init(allocator, .{
+            .size = .{
+                .dim = .{ .y = 1 },
+                .grow = .horizontal,
+            },
+        }, info_banner.element());
+        try container.append(footer);
+    }
 
     try app.start();
     defer app.stop() catch |err| log.err("Failed to stop application: {any}", .{err});
 
+    if (arg_it.next()) |path| {
+        // TODO check path is only pointing to allowed files?
+        // - only *markdown* files (file extension `.md`)
+        // - only in a specific path / directory?
+        //   -> enforce a specific structure?
+        // -> in case an invalid path is provided the 404 error page shall be shown
+        // -> reporte an corresponding error! (such that I can see that in the log)
+        var blog = path[0..path.len];
+        blog = std.mem.trimStart(u8, blog, "./");
+        blog = std.mem.trimEnd(u8, blog, ".md");
+        blog = std.mem.trimEnd(u8, blog, "/");
+        app.postEvent(.{ .blog = try std.fmt.allocPrint(allocator, "./doc/{s}.md", .{blog}) });
+    }
+    arg_it.deinit();
+
     // event loop
-    while (true) {
+    loop: while (true) {
+        // batch events since last iteration
+        const len = blk: {
+            app.queue.poll();
+            app.queue.lock();
+            defer app.queue.unlock();
+            break :blk app.queue.len();
+        };
+
         // handle events
-        const event = app.nextEvent();
+        for (0..len) |_| {
+            const event = app.queue.pop();
 
             // pre event handling
             switch (event) {
                 .key => |key| {
-                if (key.eql(.{ .cp = 'c', .mod = .{ .ctrl = true } })) app.quit();
+                    if (key.eql(.{ .cp = 'c', .mod = .{ .ctrl = true } }) or key.eql(.{ .cp = 'q' })) app.quit();
+                    // test if the event handling is working correctly
+                    if (key.eql(.{ .cp = zterm.input.Space })) app.postEvent(.{ .blog = allocator.dupe(u8, "./doc/test.md") catch unreachable });
                 },
+                .about => log.info(ResourceRequestFormat, .{"./doc/about.md"}),
+                .blog => |path| log.info(ResourceRequestFormat, .{if (path) |p| p else "./doc/blog.md"}),
                 .err => |err| log.err("Received {s} with message: {s}", .{ @errorName(err.err), err.msg }),
                 else => {},
             }
@@ -81,9 +157,10 @@ pub fn main() !void {
 
             // post event handling
             switch (event) {
-            .quit => break,
+                .quit => break :loop,
                 else => {},
             }
+        }
 
         container.resize(try renderer.resize());
         container.reposition(.{});
@@ -94,21 +171,26 @@ pub fn main() !void {
 }
 
 pub const panic = App.panic_handler;
+pub const std_options = zlog.std_options;
 const log = std.log.scoped(.default);
 
+const ResourceRequestFormat = "Requesting resource: `{s}`";
+
 const std = @import("std");
 const assert = std.debug.assert;
+const zlog = @import("zlog");
 const zterm = @import("zterm");
 const App = zterm.App(
     Model,
-    union(enum) {
-        about,
-        blog,
-    },
+    Model.Pages,
 );
 
+const contents = @import("content.zig");
 const Model = @import("model.zig");
-const Content = @import("content.zig").Content(App);
+const Content = contents.Content(App);
+const Title = contents.Title(App);
+const InfoBanner = contents.InfoBanner(App);
+const NavigationButton = @import("navigation.zig").NavigationButton(App);
 
 test {
     std.testing.refAllDeclsRecursive(@This());

src/model.zig

@@ -1,6 +1,77 @@
-page: Pages = .blog,
+page: Pages,
+document: Document,
 
-const Pages = enum {
+pub fn deinit(this: *@This(), allocator: Allocator) void {
+    this.page.deinit(allocator);
+    this.document.deinit(allocator);
+
+    this.page = undefined;
+    this.document = undefined;
+}
+
+pub const Pages = union(enum) {
     about,
-    blog,
+    blog: ?[]const u8,
+
+    pub fn deinit(this: @This(), allocator: Allocator) void {
+        switch (this) {
+            .blog => |path| if (path) |p| allocator.free(p),
+            else => {},
+        }
+    }
 };
+
+pub const Document = struct {
+    // preemble:
+    title: ?[]const u8 = null,
+    date: ?[]const u8 = null,
+    content: []const u8 = undefined,
+    ptr: []const u8,
+
+    const Preemble = enum {
+        title,
+        date,
+    };
+
+    pub const invalidPage: @This() = .{
+        .title = "Page not found",
+        .content = "Requested page does not exist",
+        .ptr = undefined,
+    };
+
+    pub fn init(content: []const u8) @This() {
+        if (std.mem.startsWith(u8, content, "---\n")) {
+            var document: @This() = .{ .ptr = content };
+            // we assume the content includes a preemble
+            var iter = std.mem.splitSequence(u8, content, "---\n");
+            assert(iter.next().?.len == 0);
+            if (iter.next()) |preemble| {
+                var lines = std.mem.splitScalar(u8, preemble, '\n');
+                while (lines.next()) |line| {
+                    var entry = std.mem.splitSequence(u8, line, ": ");
+                    const key = entry.next().?;
+                    const value = entry.next();
+                    assert(entry.next() == null);
+                    if (std.meta.stringToEnum(Preemble, key)) |k| switch (k) {
+                        .title => document.title = value,
+                        .date => document.date = value,
+                    };
+                }
+            }
+            document.content = iter.rest();
+            return document;
+        } else return .{
+            .content = content,
+            .ptr = content,
+        };
+    }
+
+    pub fn deinit(this: *@This(), allocator: Allocator) void {
+        allocator.free(this.ptr);
+        this.* = .{ .ptr = undefined };
+    }
+};
+
+const std = @import("std");
+const assert = std.debug.assert;
+const Allocator = std.mem.Allocator;

src/navigation.zig

@@ -0,0 +1,67 @@
+pub fn NavigationButton(App: type) fn (std.meta.FieldEnum(App.Event)) type {
+    const navigation_struct = struct {
+        fn navigation_fn(page: std.meta.FieldEnum(App.Event)) type {
+            return struct {
+                text: []const u8,
+                highlight: bool,
+                queue: *App.Queue,
+
+                pub fn init(model: *const App.Model, queue: *App.Queue) @This() {
+                    return .{
+                        .text = @tagName(page),
+                        .highlight = switch (page) {
+                            .about => model.page == .about,
+                            .blog => model.page == .blog,
+                            else => @compileError("NavigationButton initiated with non page `App.Event` variant"),
+                        },
+                        .queue = queue,
+                    };
+                }
+
+                pub fn element(this: *@This()) App.Element {
+                    return .{
+                        .ptr = this,
+                        .vtable = &.{
+                            .handle = handle,
+                            .content = content,
+                        },
+                    };
+                }
+
+                fn handle(ctx: *anyopaque, _: *App.Model, event: App.Event) !void {
+                    const this: *@This() = @ptrCast(@alignCast(ctx));
+                    switch (event) {
+                        .about, .blog => this.highlight = event == page,
+                        // TODO accept key input too?
+                        .mouse => |mouse| if (mouse.button == .left and mouse.kind == .release) this.queue.push(switch (page) {
+                            .about => .about,
+                            .blog => .{ .blog = null },
+                            else => @compileError("The provided navigation button event to trigger is not a `App.Model.Pages` enum variation."),
+                        }),
+                        else => {},
+                    }
+                }
+
+                fn content(ctx: *anyopaque, _: *const App.Model, cells: []zterm.Cell, size: zterm.Point) !void {
+                    const this: *const @This() = @ptrCast(@alignCast(ctx));
+                    assert(cells.len == @as(usize, size.x) * @as(usize, size.y));
+                    assert(size.x == this.text.len + 2);
+                    assert(size.y == 1);
+
+                    for (1.., this.text) |idx, cp| {
+                        cells[idx].style.fg = if (this.highlight) .black else .default;
+                        cells[idx].style.bg = if (this.highlight) .green else .default;
+                        cells[idx].style.emphasis = &.{.underline};
+                        cells[idx].cp = cp;
+                    }
+                }
+            };
+        }
+    };
+    return navigation_struct.navigation_fn;
+}
+
+const std = @import("std");
+const Allocator = std.mem.Allocator;
+const assert = std.debug.assert;
+const zterm = @import("zterm");