const std = @import("std");
const zterm = @import("zterm");

const App = zterm.App(
    union(enum) {},
    zterm.Renderer.Direct,
    true,
);
const Key = zterm.Key;
const Cell = zterm.Cell;
const Layout = App.Layout;
const Widget = App.Widget;

const log = std.log.scoped(.exec);

pub fn main() !void {
    errdefer |err| log.err("Application Error: {any}", .{err});

    var gpa: std.heap.GeneralPurposeAllocator(.{}) = .{};
    defer {
        const deinit_status = gpa.deinit();
        // fail test; can't try in defer as defer is executed after we return
        if (deinit_status == .leak) {
            log.err("memory leak", .{});
        }
    }
    const allocator = gpa.allocator();

    var app: App = .{};
    var renderer: App.Renderer = .{};
    // TODO: when not running fullscreen, the application needs to screen down accordingly to display the contents
    // -> size hint how much should it use?

    var layout = Layout.createFrom(layout: {
        var container = Layout.VContainer.init(allocator, .{
            .{
                Widget.createFrom(blk: {
                    var spacer = Widget.Spacer.init();
                    break :blk &spacer;
                }),
                45,
            },
            .{
                Layout.createFrom(framing: {
                    var framing = Layout.Framing.init(allocator, .{}, .{
                        .widget = Widget.createFrom(blk: {
                            var widget = Widget.Text.init(&[_]Cell{
                                .{ .content = "Press " },
                                .{ .content = "Ctrl+n", .style = .{ .fg = .{ .index = 6 } } },
                                .{ .content = " to launch $EDITOR" },
                            });
                            break :blk &widget;
                        }),
                    });
                    break :framing &framing;
                }),
                10,
            },
            .{
                Widget.createFrom(blk: {
                    var spacer = Widget.Spacer.init();
                    break :blk &spacer;
                }),
                45,
            },
        });
        break :layout &container;
    });
    defer layout.deinit();

    try app.start();
    defer app.stop() catch unreachable;

    // App.Event loop
    while (true) {
        const event = app.nextEvent();
        log.debug("received event: {s}", .{@tagName(event)});

        switch (event) {
            .quit => break,
            .resize => |size| {
                renderer.resize(size);
            },
            .key => |key| {
                // ctrl+c to quit
                if (Key.matches(key, .{ .cp = 'c', .mod = .{ .ctrl = true } })) {
                    app.quit();
                }
                if (Key.matches(key, .{ .cp = 'n', .mod = .{ .ctrl = true } })) {
                    try app.interrupt();
                    defer app.start() catch @panic("could not start app event loop");
                    // TODO: parse environment variables to extract the value of $EDITOR and use it here instead
                    var child = std.process.Child.init(&.{"hx"}, allocator);
                    _ = child.spawnAndWait() catch |err| {
                        app.postEvent(.{
                            .err = .{
                                .err = err,
                                .msg = "Spawning $EDITOR failed",
                            },
                        });
                    };
                }
            },
            .err => |err| {
                log.err("Received {any} with message: {s}", .{ err.err, err.msg });
            },
        }
        const events = try layout.handle(event);
        for (events.items) |e| {
            app.postEvent(e);
        }
        try layout.render(&renderer);
    }
}