zterm/examples/elements/button.zig

const std = @import("std");
const zterm = @import("zterm");

const App = zterm.App(union(enum) {
    click: [:0]const u8,
});

const log = std.log.scoped(.default);

const QuitText = struct {
    const text = "Press ctrl+c to quit.";

    pub fn element(this: *@This()) App.Element {
        return .{ .ptr = this, .vtable = &.{ .content = content } };
    }

    fn content(ctx: *anyopaque, cells: []zterm.Cell, origin: zterm.Point, size: zterm.Point) !void {
        _ = ctx;
        std.debug.assert(cells.len == @as(usize, size.x) * @as(usize, size.y));
        _ = origin;

        const row = 2;
        const col = size.x / 2 -| (text.len / 2);
        const anchor = (row * size.x) + col;

        for (text, 0..) |cp, idx| {
            cells[anchor + idx].style.fg = .white;
            cells[anchor + idx].style.bg = .black;
            cells[anchor + idx].cp = cp;

            // NOTE do not write over the contents of this `Container`'s `Size`
            if (anchor + idx == cells.len - 1) break;
        }
    }
};

const Clickable = struct {
    const text = "Press me";

    queue: *App.Queue,
    color: zterm.Color = .black,

    pub fn element(this: *@This()) App.Element {
        return .{
            .ptr = this,
            .vtable = &.{
                .handle = handle,
                .content = content,
            },
        };
    }

    fn handle(ctx: *anyopaque, event: App.Event) !void {
        const this: *@This() = @ptrCast(@alignCast(ctx));
        switch (event) {
            .mouse => |mouse| if (mouse.button == .left and mouse.kind == .release) {
                var value = @intFromEnum(this.color);
                value += 1;
                value %= 17;
                if (value == 0) value = 1;
                this.color = @enumFromInt(value);
                this.queue.push(.{ .click = @tagName(mouse.button) });
            },
            else => {},
        }
    }

    fn content(ctx: *anyopaque, cells: []zterm.Cell, origin: zterm.Point, size: zterm.Point) !void {
        const this: *@This() = @ptrCast(@alignCast(ctx));
        std.debug.assert(cells.len == @as(usize, size.x) * @as(usize, size.y));
        _ = origin;

        const row = size.y / 2 -| (text.len / 2);
        const col = size.x / 2 -| (text.len / 2);
        const anchor = (row * size.x) + col;

        for (text, 0..) |cp, idx| {
            cells[anchor + idx].style.fg = this.color;
            cells[anchor + idx].style.emphasis = &.{.bold};
            cells[anchor + idx].cp = cp;

            // NOTE do not write over the contents of this `Container`'s `Size`
            if (anchor + idx == cells.len - 1) break;
        }
    }
};

pub fn main() !void {
    errdefer |err| log.err("Application Error: {any}", .{err});

    var gpa: std.heap.GeneralPurposeAllocator(.{}) = .init;
    defer if (gpa.deinit() == .leak) log.err("memory leak", .{});

    const allocator = gpa.allocator();

    var app: App = .init;
    var renderer = zterm.Renderer.Buffered.init(allocator);
    defer renderer.deinit();

    var clickable: Clickable = .{ .queue = &app.queue };
    const element = clickable.element();

    var quit_text: QuitText = .{};

    var container = try App.Container.init(allocator, .{
        .rectangle = .{ .fill = .grey },
        .layout = .{ .padding = .all(5) },
    }, quit_text.element());
    defer container.deinit();

    try container.append(try App.Container.init(allocator, .{ .rectangle = .{ .fill = .light_grey } }, element));

    try app.start();
    defer app.stop() catch |err| log.err("Failed to stop application: {any}", .{err});

    // event loop
    while (true) {
        const event = app.nextEvent();
        log.debug("received event: {s}", .{@tagName(event)});

        // pre event handling
        switch (event) {
            .key => |key| if (key.eql(.{ .cp = 'c', .mod = .{ .ctrl = true } })) app.quit(),
            .click => |button| {
                log.info("Clicked with mouse using Button: {s}", .{button});
            },
            .err => |err| log.err("Received {s} with message: {s}", .{ @errorName(err.err), err.msg }),
            else => {},
        }

        container.handle(event) catch |err| app.postEvent(.{
            .err = .{
                .err = err,
                .msg = "Container Event handling failed",
            },
        });

        // post event handling
        switch (event) {
            .quit => break,
            else => {},
        }

        try renderer.resize();
        container.reposition(.{});
        container.resize(renderer.size);
        try renderer.render(@TypeOf(container), &container);
        try renderer.flush();
    }
}