zterm/examples/layouts/mixed.zig

const QuitText = struct {
    const text = "Press ctrl+c to quit.";

    pub fn element(this: *@This()) App.Element {
        return .{
            .ptr = this,
            .vtable = &.{ .content = content },
        };
    }

    fn content(ctx: *anyopaque, _: *const App.Model, cells: []zterm.Cell, size: zterm.Point) !void {
        _ = ctx;
        assert(cells.len == @as(usize, size.x) * @as(usize, size.y));

        const row = 2;
        const col = size.x / 2 -| (text.len / 2);
        const anchor = (row * size.x) + col;

        for (text, 0..) |cp, idx| {
            cells[anchor + idx].style.fg = .white;
            cells[anchor + idx].style.bg = .black;
            cells[anchor + idx].cp = cp;

            // NOTE do not write over the contents of this `Container`'s `Size`
            if (anchor + idx == cells.len - 1) break;
        }
    }
};

pub fn main() !void {
    errdefer |err| log.err("Application Error: {any}", .{err});

    var gpa: std.heap.DebugAllocator(.{}) = .init;
    defer if (gpa.deinit() == .leak) log.err("memory leak", .{});

    const allocator = gpa.allocator();

    var app: App = .init(.{});
    var renderer = zterm.Renderer.Buffered.init(allocator);
    defer renderer.deinit();

    var quit_text: QuitText = .{};
    const element = quit_text.element();

    var container = try App.Container.init(allocator, .{
        .layout = .{
            .gap = 2,
            .padding = .{ .top = 5, .bottom = 3, .left = 3, .right = 3 },
        },
    }, element);
    for (0..3) |i| {
        var column = try App.Container.init(allocator, .{
            .layout = .{
                .separator = .{ .enabled = true },
                .direction = if (i > 0) .vertical else .horizontal,
            },
        }, .{});
        if (i != 1) {
            try column.append(try App.Container.init(allocator, .{
                .rectangle = .{ .fill = .green },
            }, .{}));
            try column.append(try App.Container.init(allocator, .{
                .rectangle = .{ .fill = .yellow },
            }, .{}));
        } else {
            try column.append(try App.Container.init(allocator, .{
                .size = .{
                    .dim = .{ .y = 4 },
                    .grow = .horizontal,
                },
            }, .{}));
        }
        try column.append(try App.Container.init(allocator, .{
            .rectangle = .{ .fill = .blue },
        }, .{}));
        try container.append(column);
    }
    defer container.deinit(); // also de-initializes the children

    try app.start();
    defer app.stop() catch |err| log.err("Failed to stop application: {any}", .{err});

    // event loop
    while (true) {
        const event = app.nextEvent();
        log.debug("received event: {s}", .{@tagName(event)});

        // pre event handling
        switch (event) {
            .key => |key| if (key.eql(.{ .cp = 'c', .mod = .{ .ctrl = true } })) app.quit(),
            // NOTE errors could be displayed in another container in case one was received, etc. to provide the user with feedback
            .err => |err| log.err("Received {s} with message: {s}", .{ @errorName(err.err), err.msg }),
            else => {},
        }

        // NOTE returned errors should be propagated back to the application
        container.handle(&app.model, event) catch |err| app.postEvent(.{
            .err = .{
                .err = err,
                .msg = "Container Event handling failed",
            },
        });

        // post event handling
        switch (event) {
            .quit => break,
            else => {},
        }

        container.resize(try renderer.resize());
        container.reposition(.{});
        try renderer.render(@TypeOf(container), &container, App.Model, &app.model);
        try renderer.flush();
    }
}

pub const panic = App.panic_handler;
const log = std.log.scoped(.default);

const std = @import("std");
const assert = std.debug.assert;
const zterm = @import("zterm");
const App = zterm.App(struct {}, union(enum) {});